এখানে Google বিজ্ঞাপন কোয়েরি ভাষার ব্যাকরণের রেফারেন্স (রেগুলার এক্সপ্রেশন নোটেশনে):
Query -> SelectClause FromClause WhereClause? OrderByClause?
LimitClause? ParametersClause?
SelectClause -> SELECT FieldName (, FieldName)*
FromClause -> FROM ResourceName
WhereClause -> WHERE Condition (AND Condition)*
OrderByClause -> ORDER BY Ordering (, Ordering)*
LimitClause -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*
Condition -> FieldName Operator Value
Operator -> = | != | > | >= | < | <= | IN | NOT IN |
LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value -> Literal | LiteralList | Number | NumberList | String |
StringList | Function
Ordering -> FieldName (ASC | DESC)?
FieldName -> [a-z] ([a-zA-Z0-9._])*
ResourceName -> [a-z] ([a-zA-Z_])*
StringList -> ( String (, String)* )
LiteralList -> ( Literal (, Literal)* )
NumberList -> ( Number (, Number)* )
PositiveInteger -> [1-9] ([0-9])*
Number -> -? [0-9]+ (. [0-9] [0-9]*)?
String -> (' Char* ') | (" Char* ")
Literal -> [a-zA-Z0-9_]*
Function -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
? একটি ঐচ্ছিক উপাদান নির্দেশ করে
* মানে শূন্য বা তার বেশি; + মানে এক বা একাধিক
(xxxxxx) একটি গ্রুপিং নির্দেশ করে
[a-z0-9] অক্ষরের ব্যাপ্তি বোঝায়
| "বা" এর জন্য দাঁড়ায়
নিয়ম এবং সীমাবদ্ধতা
REGEXP_MATCHঅপারেটর RE2 সিনট্যাক্স ব্যবহার করে।LIKEঅপারেটর ব্যবহার করে একটি আক্ষরিক[,],%, বা_এর সাথে মেলাতে, অক্ষরটিকে বর্গাকার বন্ধনীতে ঘিরে দিন। উদাহরণ স্বরূপ, নিম্নলিখিত শর্তগুলি[Earth_to_Mars]দিয়ে শুরু হওয়া সমস্তcampaign.nameমানগুলির সাথে মেলে:campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'LIKEঅপারেটর শুধুমাত্র একটি স্ট্রিং ক্ষেত্রে ব্যবহার করা যেতে পারে, একটি অ্যারে নয়।