Google বিজ্ঞাপন কোয়েরি ভাষার ব্যাকরণ

ভিডিও: কোয়েরি যাচাইকরণ

এই পৃষ্ঠায় গুগল অ্যাডস কোয়েরি ল্যাঙ্গুয়েজের ব্যাকরণগত নির্দেশিকা রয়েছে। কোয়েরির গঠন সম্পর্কে বিস্তারিত জানতে, কোয়েরি স্ট্রাকচার (Query Structure) দেখুন।

এখানে গুগল অ্যাডস কোয়েরি ল্যাঙ্গুয়েজের ব্যাকরণগত নির্দেশিকা দেওয়া হলো (রেগুলার এক্সপ্রেশন পদ্ধতিতে):

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

? একটি ঐচ্ছিক উপাদান নির্দেশ করে
* মানে শূন্য বা তার বেশি; + মানে এক বা একাধিক
(xxxxxx) একটি দলবদ্ধকরণ নির্দেশ করে
[a-z0-9] অক্ষরের পরিসর নির্দেশ করে
| এর অর্থ "অথবা"

নিয়ম ও সীমাবদ্ধতা

• REGEXP_MATCH অপারেটরটি RE2 সিনট্যাক্স ব্যবহার করে।

• LIKE অপারেটর ব্যবহার করে কোনো আক্ষরিক [ , ] , % , বা _ চিহ্নকে মেলানোর জন্য, অক্ষরটিকে বর্গাকার বন্ধনীর মধ্যে রাখুন। উদাহরণস্বরূপ, নিম্নলিখিত শর্তটি campaign.name সেই সমস্ত মানকে মেলায় যা [Earth_to_Mars] দিয়ে শুরু হয়:

  campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
  

• LIKE অপারেটরটি শুধুমাত্র স্ট্রিং ফিল্ডে ব্যবহার করা যায়, অ্যারেতে নয়।