Mask kolom

Di Google Ads API, update dilakukan menggunakan mask kolom. Mask kolom mencantumkan semua kolom yang ingin Anda ubah dengan update, dan kolom tertentu yang tidak ada dalam mask kolom akan diabaikan, meskipun dikirim ke server.

Utilitas FieldMasks

Cara yang direkomendasikan untuk membuat mask kolom adalah menggunakan utilitas mask kolom bawaan kami (FieldMasks), yang memungkinkan Anda membuat mask kolom dari objek yang diubah, bukan membuatnya dari awal.

Berikut adalah contoh untuk memperbarui kampanye:

use Google::Ads::GoogleAds::Utils::FieldMasks qw(all_set_fields_of field_mask);

my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => "PAUSED",
    networkSettings =>
      Google::Ads::GoogleAds::V26::Resources::NetworkSettings
      ->new({
        targetSearchNetwork => "false",
      }),
  });

my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

Contoh ini pertama-tama membuat objek Campaign dengan menetapkan nama resource-nya menggunakan utilitas ResourceNames, sehingga API mengetahui kampanye mana yang sedang diperbarui.

Contoh ini menggunakan metode FieldMasks::all_set_fields_of() pada kampanye untuk otomatis menghasilkan mask kolom yang menghitung semua kolom yang ditetapkan. Kemudian, Anda dapat meneruskan mask yang ditampilkan langsung ke panggilan update.

FieldMasks::all_set_fields_of() adalah metode praktis untuk FieldMasks::field_mask(). Metode ini membandingkan objek yang Anda teruskan dengan objek kosong dari class yang sama. Dalam kode sebelumnya, Anda juga dapat menggunakan:

field_mask(
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({}),
  $campaign
)

bukan all_set_fields_of($campaign).

Membuat mask secara manual

Untuk membuat mask kolom dari awal, pertama-tama buat objek Google::Ads::GoogleAds::Common::FieldMask, lalu buat referensi array yang diisi dengan nama semua kolom yang ingin Anda ubah, dan terakhir tetapkan referensi array ke kolom paths mask kolom:

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
  paths => ["status", "name"],
});

Memperbarui kolom objek dan subkolomnya

Kolom objek dapat memiliki subkolom (seperti MaximizeConversions, yang mencakup subkolom seperti target_cpa_micros), atau tidak memiliki subkolom sama sekali (seperti ManualCpm).

Kolom objek tanpa subkolom yang ditentukan

Kolom objek di Perl setara dengan MESSAGE protobuf di library klien yang berjalan di gRPC. Saat memperbarui kolom objek yang tidak ditentukan dengan subkolom apa pun, gunakan utilitas FieldMasks untuk membuat mask kolom, seperti yang dijelaskan di bagian sebelumnya.

Kolom objek dengan subkolom yang ditentukan

Saat memperbarui kolom objek yang ditentukan dengan subkolom tanpa menetapkan subkolom apa pun secara eksplisit pada pesan tersebut, Anda harus menambahkan setiap subkolom objek yang dapat diubah ke FieldMask secara manual, mirip dengan contoh sebelumnya yang membuat mask kolom dari awal.

Salah satu contoh umumnya adalah memperbarui strategi bidding kampanye tanpa menetapkan kolom apa pun pada strategi bidding baru. Contoh berikut menunjukkan cara memperbarui kampanye untuk menggunakan strategi bidding MaximizeConversions tanpa menetapkan subkolom apa pun pada strategi bidding.

Dalam hal ini, penggunaan metode all_set_fields_of() dan field_mask() dari utilitas FieldMasks tidak mencapai sasaran yang diinginkan.

Contoh berikut membuat mask kolom yang menyertakan maximize_conversions. Namun, Google Ads API tidak mengizinkan perilaku ini untuk mencegah kolom terhapus secara tidak sengaja, dan menghasilkan FieldMaskError.FIELD_HAS_SUBFIELDS error.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new(),
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask includes 'maximize_conversions',
# which produces a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

# Sends the operation in a mutate request that results in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
  customerId => $customer_id,
  operations => [$campaign_operation],
});

Contoh berikut menunjukkan cara memperbarui kampanye dengan benar untuk menggunakan strategi bidding MaximizeConversions tanpa menetapkan subkolomnya.

# Creates a campaign with the proper resource name.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
  });

# Creates a field mask from the existing campaign and adds the mutable subfield
# on the MaximizeConversions bidding strategy to the field mask. Because this
# field is included in the field mask but excluded from the campaign object,
# the Google Ads API sets the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# See the guide on assigning standard and portfolio bidding strategies
# (/google-ads/api/docs/campaigns/bidding/assign-strategies).
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => $field_mask,
  });

Hapus kolom

Kolom dapat dihapus secara eksplisit dengan menambahkannya ke mask kolom seperti yang ditunjukkan dalam contoh sebelumnya, atau dengan menetapkan kolom ke nilai kosong atau tidak ditentukan. Misalnya, asumsikan Anda memiliki kampanye yang menggunakan strategi bidding MaximizeConversions dan kolom target_cpa_micros ditetapkan dengan nilai yang lebih besar dari 0.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new({
        targetCpaMicros => 0,
      }),
  });

# Constructs an operation using all_set_fields_of to derive the update mask,
# which includes 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

Perhatikan bahwa kolom dengan subkolom bertingkat hanya dapat dihapus dengan menghapus setiap subkolom satu per satu, seperti yang ditunjukkan di Kolom objek dengan subkolom yang ditentukan.