Bu sayfa, Cloud Translation API ile çevrilmiştir.

Alan Maskeleri

Google Ads API'de güncellemeler bir alan maskesi kullanılarak yapılır. Alan maskesi, güncellemeyle değiştirmek istediğiniz tüm alanları listeler ve alan maskesinde bulunmayan belirtilen alanlar sunucuya gönderilseler bile yoksayılır.

FieldMasks yardımcı programı

Alan maskeleri oluşturmak için önerilen yöntem, sıfırdan oluşturmak yerine değiştirilmiş bir nesneden alan maskeleri oluşturmanıza olanak tanıyan yerleşik alan maskesi yardımcı aracımızı (FieldMasks) kullanmaktır.

Aşağıda, bir kampanyayı güncellemeyle ilgili bir örnek verilmiştir:

my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V16::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Bu örnek ilk olarak ResourceNames yardımcı programını kullanarak kaynak adını ayarlayarak bir Campaign nesnesi oluşturur. Böylece API, hangi kampanyanın güncellendiğini bilir.

Örnek, ayarlanan tüm alanları numaralandıran bir alan maskesini otomatik olarak oluşturmak için kampanyada FieldMasks::all_set_fields_of() yöntemini kullanır. Ardından, döndürülen maskeyi doğrudan güncelleme çağrısına aktarabilirsiniz.

FieldMasks::all_set_fields_of(), FieldMasks::field_mask() için basit bir yöntemdir. Geçirdiğiniz nesneyi aynı sınıftaki boş bir nesneyle karşılaştırır. Yukarıdaki kodda

field_mask(Google::Ads::GoogleAds::V16::Resources::Campaign->new({}), $campaign)

all_set_fields_of($campaign) yerine).

Manuel olarak maske oluşturma

Sıfırdan alan maskesi oluşturmak için önce bir Google::Ads::GoogleAds::Common::FieldMask nesnesi oluşturur, ardından değiştirmek istediğiniz tüm alanların adlarıyla doldurulmuş bir dizi referansı oluşturursunuz ve son olarak dizi referansını alan maskesinin paths alanına atarsınız.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Nesne alanlarını ve alt alanlarını güncelleme

Nesne alanlarının alt alanları olabilir (örneğin üç adet target_cpa_micros, cpc_bid_ceiling_micros ve cpc_bid_floor_micros içeren MaximizeConversions) veya hiç alt alanları olamaz (ManualCpm gibi).

Tanımlı alt alanı olmayan nesne alanları

Perl'deki bir nesne alanı, gRPC üzerinde çalışan istemci kitaplıklarındaki bir protobuf MESSAGE'e eşdeğerdir. Alt alanlarla tanımlanmayan bir nesne alanını güncellerken, yukarıda açıklandığı gibi bir alan maskesi oluşturmak için FieldMasks yardımcı programını kullanın.

Tanımlı alt alanları olan nesne alanları

Alt alanlarla tanımlanmış bir nesne alanını bu iletideki alt alanların herhangi birini açıkça ayarlamadan güncellerken, sıfırdan alan maskesi oluşturan yukarıdaki örnekte olduğu gibi, değişebilir nesne alt alanlarının her birini manuel olarak FieldMask öğesine eklemeniz gerekir.

Yaygın bir örnek, yeni teklif stratejisindeki alanların hiçbirini ayarlamadan bir kampanyanın teklif stratejisini güncellemektir. Aşağıdaki örnekte, teklif stratejisinin alt alanlarını ayarlamadan bir kampanyayı MaximizeConversions teklif stratejisini kullanacak şekilde nasıl güncelleyeceğiniz gösterilmektedir.

Bu durumda, FieldMasks yardımcı programının all_set_fields_of() ve field_mask() yöntemlerinin kullanılması, amaçlanan hedefe ulaşmaz.

Aşağıdaki örnek, maximize_conversions değerini içeren bir alan maskesi oluşturur. Ancak Google Ads API, alanların yanlışlıkla temizlenmesini ve bir FieldMaskError.FIELD_HAS_SUBFIELDS hatasına neden olmasını önlemek için bu davranışa izin vermez.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Aşağıdaki örnekte, bir kampanyayı alt alanlarından herhangi birini ayarlamadan MaximizeConversions teklif stratejisini kullanacak şekilde doğru şekilde nasıl güncelleyeceğiniz gösterilmektedir.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Alanlar temizleniyor

Alanlar, yukarıda gösterildiği gibi alan maskesine eklenerek veya alanı boş ya da tanımlanmamış bir değere ayarlanarak açıkça temizlenebilir. Örneğin, MaximizeConversions teklif stratejisi kullanan bir kampanyanız olduğunu ve target_cpa_micros alanının 0 üzerinde bir değere ayarlandığını varsayalım.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

İç içe alt alanları olan alanların, Tanımlanmış alt alanları olan nesne alanları bölümünde gösterildiği gibi yalnızca bağımsız alt alanların her biri temizlenerek temizlenebileceğini unutmayın.