Полевые маски

В API Google Ads обновления выполняются с помощью маски полей. В маске полей перечислены все поля, которые вы планируете изменить при обновлении. Любые указанные поля, не входящие в маску, игнорируются, даже если они отправлены на сервер.

Утилита FieldMasks

Рекомендуемый способ создания масок полей — использование нашей встроенной утилиты создания масок полей ( FieldMasks ), которая позволяет создавать маски полей из измененного объекта, а не создавать их с нуля.

Вот пример обновления кампании:

my $campaign = Google::Ads::GoogleAds::V20::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V20::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V20::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V20::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

В этом примере сначала создается объект Campaign путем установки имени его ресурса с помощью утилиты ResourceNames , чтобы API знал, какая кампания обновляется.

В этом примере метод FieldMasks::all_set_fields_of() кампании автоматически генерирует маску полей, перечисляющую все заданные поля. Затем полученную маску можно передать непосредственно в вызов обновления.

FieldMasks::all_set_fields_of() — это удобный метод для FieldMasks::field_mask() . Он сравнивает переданный объект с пустым объектом того же класса. Поэтому в приведённом выше коде вы также можете использовать

field_mask(Google::Ads::GoogleAds::V20::Resources::Campaign->new({}), $campaign)

вместо all_set_fields_of($campaign) .

Создание маски вручную

Чтобы создать маску поля с нуля, сначала необходимо создать объект Google::Ads::GoogleAds::Common::FieldMask , затем создать ссылку на массив, заполненную именами всех полей, которые вы собираетесь изменить, и, наконец, назначить ссылку на массив полю paths маски поля.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Обновление полей объекта и их подполей

Поля объекта могут иметь подполя (например, MaximizeConversions , у которого их три: target_cpa_micros , cpc_bid_ceiling_micros и cpc_bid_floor_micros ); или они могут не иметь ни одного (например, ManualCpm ).

Поля объекта без определенных подполей

Поле объекта в Perl эквивалентно PROTOBUF- MESSAGE в клиентских библиотеках, работающих на gRPC. При обновлении поля объекта, для которого не определены подполя, используйте утилиту FieldMasks для генерации маски поля, как описано выше.

Поля объектов с определенными подполями

При обновлении поля объекта, которое определено с подполями, без явной установки каких-либо подполей в этом сообщении, необходимо вручную добавить каждое из изменяемых подполей объекта в FieldMask , аналогично примеру выше, в котором маска поля создается с нуля.

Одним из распространённых примеров является обновление стратегии назначения ставок кампании без настройки каких-либо полей в новой стратегии. В примере ниже показано, как обновить кампанию для использования стратегии назначения ставок MaximizeConversions без настройки каких-либо подполей в стратегии назначения ставок.

В этом случае использование методов all_set_fields_of() и field_mask() утилиты FieldMasks не достигает поставленной цели.

В следующем примере генерируется маска поля, включающая maximize_conversions . Однако API Google Ads не допускает такого поведения, чтобы предотвратить случайную очистку полей, и выдаёт ошибку FieldMaskError.FIELD_HAS_SUBFIELDS .

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V20::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V20::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V20::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V20::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

В следующем примере показано, как правильно обновить кампанию для использования стратегии назначения ставок MaximizeConversions без настройки каких-либо ее подполей.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V20::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V20::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V20::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Очистка полей

Поля можно очистить явно, добавив их в маску поля, как показано выше, или установив поле пустым или неопределённым значением. Например, предположим, что у вас есть кампания со стратегией назначения ставок MaximizeConversions , и поле target_cpa_micros имеет значение больше 0 .

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V20::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V20::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V20::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V20::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Обратите внимание, что поля с вложенными подполями можно очистить только путем очистки каждого из отдельных подполей, как показано в разделе Поля объектов с определенными подполями .