Feldmasken

In der Google Ads API erfolgen Aktualisierungen mithilfe einer Feldmaske. Die Feldmaske listet alle Felder auf, die Sie mit der Aktualisierung ändern möchten. Alle angegebenen Felder, die nicht in der Feldmaske enthalten sind, werden ignoriert, selbst wenn sie an den Server gesendet werden.

FieldMasks-Dienstprogramm

Die empfohlene Methode zum Generieren von Feldmasken ist die Verwendung unseres integrierten Dienstprogramms für Feldmasken (FieldMasks). Damit können Sie Feldmasken aus einem geänderten Objekt generieren, anstatt sie von Grund auf neu zu erstellen.

Hier ein Beispiel für die Aktualisierung einer Kampagne:

my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V16::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

In diesem Beispiel wird zuerst ein Campaign-Objekt erstellt. Dazu wird der Ressourcenname mit dem ResourceNames-Dienstprogramm festgelegt, sodass die API weiß, welche Kampagne aktualisiert wird.

Im Beispiel wird die Methode FieldMasks::all_set_fields_of() für die Kampagne verwendet, um automatisch eine Feldmaske zu erstellen, die alle festgelegten Felder aufzählt. Sie können die zurückgegebene Maske dann direkt an den Aktualisierungsaufruf übergeben.

FieldMasks::all_set_fields_of() ist eine praktische Methode für FieldMasks::field_mask(). Dabei wird das übergebene Objekt mit einem leeren Objekt derselben Klasse verglichen. Im Code oben könnten Sie also auch

field_mask(Google::Ads::GoogleAds::V16::Resources::Campaign->new({}), $campaign)

statt all_set_fields_of($campaign).

Maske manuell erstellen

Um eine neue Feldmaske zu erstellen, müssen Sie zuerst ein Google::Ads::GoogleAds::Common::FieldMask-Objekt erstellen, dann einen Arrayverweis mit den Namen aller Felder erstellen, die Sie ändern möchten, und schließlich den Arrayverweis dem Feld paths der Feldmaske zuweisen.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Objektfelder und ihre Unterfelder aktualisieren

Objektfelder können Unterfelder haben (z. B. MaximizeConversions mit drei Feldern: target_cpa_micros, cpc_bid_ceiling_micros und cpc_bid_floor_micros) oder gar keines (z. B. ManualCpm).

Objektfelder ohne definierte Unterfelder

Ein Objektfeld in Perl entspricht einem protobuf-MESSAGE in Clientbibliotheken, die auf gRPC ausgeführt werden. Wenn Sie ein Objektfeld aktualisieren, das nicht mit Unterfeldern definiert ist, generieren Sie mit dem Dienstprogramm „FieldMasks“ wie oben beschrieben eine Feldmaske.

Objektfelder mit definierten Unterfeldern

Wenn Sie ein Objektfeld aktualisieren, das mit Unterfeldern definiert ist, ohne explizit eines der Unterfelder in dieser Nachricht festzulegen, müssen Sie jedes änderbare Objekt-Unterfeld manuell zu FieldMask hinzufügen, ähnlich wie im obigen Beispiel, bei dem eine neue Feldmaske erstellt wird.

Ein gängiges Beispiel ist das Aktualisieren der Gebotsstrategie einer Kampagne, ohne eines der Felder in der neuen Gebotsstrategie festzulegen. Das folgende Beispiel zeigt, wie Sie eine Kampagne aktualisieren, um die Gebotsstrategie MaximizeConversions zu verwenden, ohne eines der untergeordneten Felder der Gebotsstrategie festzulegen.

In diesem Fall wird mit den Methoden all_set_fields_of() und field_mask() des FieldMasks-Dienstprogramms das beabsichtigte Ziel nicht erreicht.

Im folgenden Beispiel wird eine Feldmaske generiert, die maximize_conversions enthält. Die Google Ads API lässt dies jedoch nicht zu. Damit wird verhindert, dass Felder versehentlich gelöscht werden und der Fehler FieldMaskError.FIELD_HAS_SUBFIELDS ausgegeben wird.

Warnung: Der folgende Code führt zu einem Fehler.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Das folgende Beispiel zeigt, wie eine Kampagne ordnungsgemäß für die Verwendung der Gebotsstrategie MaximizeConversions aktualisiert wird, ohne eines ihrer Unterfelder festzulegen.

Erfolgreich :Die Gebotsstrategie für die Kampagne wurde mit dem folgenden Code aktualisiert.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Felder löschen

Felder können explizit gelöscht werden, indem sie der Feldmaske wie oben gezeigt hinzugefügt werden oder indem das Feld auf einen leeren oder nicht definierten Wert gesetzt wird. Angenommen, Sie haben eine Kampagne, in der die Gebotsstrategie MaximizeConversions verwendet wird, und für das Feld target_cpa_micros ist ein Wert größer als 0 festgelegt.

Erfolgreich: Mit dem folgenden Code wird das Feld target_cpa_micros gelöscht.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Felder mit verschachtelten Unterfeldern können nur gelöscht werden, indem die einzelnen Unterfelder gelöscht werden, wie unter Objektfelder mit definierten Unterfeldern dargestellt.