أقنعة الحقل

في Google Ads API، يتم إجراء التعديلات باستخدام قناع حقل. يسرد قناع الحقل جميع الحقول التي تنوي تغييرها من خلال التحديث، ويتم تجاهل أي حقول محددة غير موجودة في قناع الحقل، حتى إذا تم إرسالها إلى الخادم.

خدمة أقنعة ميدانية

إنّ الطريقة المُقترَحة لإنشاء أقنعة الحقول هي استخدام أداة قناع الحقل المدمجة (FieldMasks)، التي تتيح لك إنشاء أقنعة حقل من عنصر معدَّل بدلاً من إنشائها من البداية.

في ما يلي مثال على تعديل إحدى الحملات:

my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V16::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

في هذا المثال، يتم أولاً إنشاء عنصر Campaign من خلال ضبط اسم مورده باستخدام الأداة المساعدة ResourceNames، حتى تتعرّف واجهة برمجة التطبيقات على الحملة التي يتم تعديلها.

يستخدم المثال الطريقة FieldMasks::all_set_fields_of() في الحملة لإنشاء قناع حقل يسرد جميع الحقول المحددة تلقائيًا. يمكنك بعد ذلك تمرير القناع الذي تم إرجاعه مباشرةً إلى المكالمة المتعلقة بالتحديث.

FieldMasks::all_set_fields_of() هي طريقة ملائمة FieldMasks::field_mask(). ويقارن ذلك الكائن الذي تم تمريره بعنصر فارغ من الفئة نفسها. لذلك في التعليمات البرمجية أعلاه، يمكنك أيضًا استخدام

field_mask(Google::Ads::GoogleAds::V16::Resources::Campaign->new({}), $campaign)

بدلاً من all_set_fields_of($campaign).

إنشاء كمامة يدويًا

لإنشاء قناع حقل من البداية، عليك أولاً إنشاء كائن Google::Ads::GoogleAds::Common::FieldMask، ثم إنشاء مرجع صفيف مملوء بأسماء كل الحقول التي تنوي تغييرها، وأخيرًا تخصيص مرجع الصفيفة إلى الحقل paths الخاص بقناع الحقل.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

تحديث حقول الكائنات وحقولها الفرعية

يمكن أن تحتوي حقول العناصر على حقول فرعية (مثل MaximizeConversions التي تتضمّن ثلاثة: target_cpa_micros وcpc_bid_ceiling_micros وcpc_bid_floor_micros)، أو قد لا تحتوي على أي منها على الإطلاق (مثل ManualCpm).

حقول عناصر بدون حقول فرعية محدّدة

حقل الكائنات في Perl يُعادل حقل MESSAGE النموذجي في مكتبات العملاء التي تعمل على gRPC. عند تحديث حقل كائن لم يتم تعريفه بأي حقول فرعية، استخدم الأداة المساعدة FieldMasks لإنشاء قناع حقل، كما هو موضح أعلاه.

حقول العناصر ذات الحقول الفرعية المحدّدة

عند تعديل حقل كائن تم تحديده بحقول فرعية بدون التحديد صراحةً لأي من الحقول الفرعية في تلك الرسالة، عليك إضافة كل حقل من الحقول الفرعية الخاصة بالكائنات القابلة للتغيير يدويًا إلى FieldMask، على غرار المثال أعلاه الذي ينشئ قناع حقل من البداية.

ومن الأمثلة الشائعة على ذلك تعديل استراتيجية عروض الأسعار في الحملة بدون ضبط أيٍّ من الحقول في استراتيجية عروض الأسعار الجديدة. يوضِّح المثال التالي كيفية تعديل حملة لاستخدام استراتيجية عروض الأسعار في MaximizeConversions بدون إعداد أي من الحقول الفرعية في استراتيجية عروض الأسعار.

في هذه الحالة، لا يؤدي استخدام الطريقتَين all_set_fields_of() وfield_mask() من أداة FieldMasks إلى تحقيق الهدف المنشود.

ينشئ المثال التالي قناع حقل يتضمن maximize_conversions. في المقابل، لا تسمح Google Ads API بهذا السلوك، لمنع محو الحقول عن طريق الخطأ وعرض خطأ FieldMaskError.FIELD_HAS_SUBFIELDS.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

يوضِّح المثال التالي كيفية تعديل إحدى الحملات بشكلٍ سليم لاستخدام استراتيجية عروض الأسعار "MaximizeConversions" بدون إعداد أي من حقولها الفرعية.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

جارٍ محو الحقول.

يمكن محو الحقول بشكل صريح من خلال إضافتها إلى قناع الحقل كما هو موضّح أعلاه، أو من خلال ضبط الحقل على قيمة فارغة أو غير محدّدة. على سبيل المثال، لنفترض أنّ لديك حملة تستخدم استراتيجية عروض الأسعار "MaximizeConversions" وأنّه تم ضبط الحقل "target_cpa_micros" بقيمة أكبر من "0".

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V16::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V16::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

يُرجى العلم أنّه لا يمكن محو الحقول التي تتضمّن حقولاً فرعية مضمّنة إلا من خلال محو كل حقل من الحقول الفرعية الفردية، كما هو موضَّح في مقالة حقول العناصر ذات الحقول الفرعية المحدَّدة.