Feldmasken

In der Google Ads API werden Aktualisierungen mit einer Feldmaske vorgenommen. In der Feldmaske sind alle Felder aufgeführt, die Sie mit der Aktualisierung ändern möchten. Alle angegebenen Felder, die nicht in der Feldmaske enthalten sind, werden ignoriert, auch wenn sie an den Server gesendet werden.

Dienstprogramm „FieldMasks“

Die empfohlene Methode zum Generieren von Feldmasken ist die Verwendung unseres integrierten Dienstprogramms für Feldmasken (FieldMasks). Damit können Sie Feldmasken aus einem geänderten Objekt generieren, anstatt sie von Grund auf neu zu erstellen.

Hier ein Beispiel für die Aktualisierung einer Kampagne:

use Google::Ads::GoogleAds::Utils::FieldMasks qw(all_set_fields_of field_mask);

my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => "PAUSED",
    networkSettings =>
      Google::Ads::GoogleAds::V26::Resources::NetworkSettings
      ->new({
        targetSearchNetwork => "false",
      }),
  });

my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

In diesem Beispiel wird zuerst ein Campaign Objekt erstellt, indem der Ressourcenname mit dem Dienstprogramm ResourceNames festgelegt wird, damit die API weiß, welche Kampagne aktualisiert wird.

Im Beispiel wird die FieldMasks::all_set_fields_of() Methode für die Kampagne verwendet, um automatisch eine Feldmaske zu erstellen, in der alle festgelegten Felder aufgeführt sind. Sie können die zurückgegebene Maske dann direkt an den Aktualisierungsaufruf übergeben.

FieldMasks::all_set_fields_of() ist eine Hilfsmethode für FieldMasks::field_mask(). Dabei wird das übergebene Objekt mit einem leeren Objekt derselben Klasse verglichen. Im vorherigen Code können Sie auch Folgendes verwenden:

field_mask(
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({}),
  $campaign
)

anstelle von all_set_fields_of($campaign).

Maske manuell erstellen

Wenn Sie eine Feldmaske von Grund auf neu erstellen möchten, erstellen Sie zuerst ein Google::Ads::GoogleAds::Common::FieldMask-Objekt. Erstellen Sie dann eine Array-Referenz, die mit den Namen aller Felder gefüllt ist, die Sie ändern möchten, und weisen Sie die Array-Referenz schließlich dem Feld paths der Feldmaske zu:

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
  paths => ["status", "name"],
});

Objektfelder und ihre Unterfelder aktualisieren

Objektfelder können Unterfelder haben (z. B. MaximizeConversions mit Unterfeldern wie target_cpa_micros) oder keine (z. B. ManualCpm).

Objektfelder ohne definierte Unterfelder

Ein Objektfeld in Perl entspricht einem Protobuf-MESSAGE in Clientbibliotheken, die unter gRPC ausgeführt werden. Wenn Sie ein Objektfeld aktualisieren, für das keine Unterfelder definiert sind, verwenden Sie das Dienstprogramm FieldMasks, um eine Feldmaske zu generieren, wie im vorherigen Abschnitt beschrieben.

Objektfelder mit definierten Unterfeldern

Wenn Sie ein Objektfeld aktualisieren, das mit Unterfeldern definiert ist, ohne eines der Unterfelder in dieser Nachricht explizit festzulegen, müssen Sie jedes der änderbaren Objektunterfelder manuell zur FieldMask hinzufügen. Das ist ähnlich wie im vorherigen Beispiel, in dem eine Feldmaske von Grund auf neu erstellt wird.

Ein häufiges Beispiel ist die Aktualisierung der Gebotsstrategie einer Kampagne, ohne die Felder für die neue Gebotsstrategie festzulegen. Im folgenden Beispiel wird gezeigt, wie Sie eine Kampagne so aktualisieren, dass die MaximizeConversions Gebotsstrategie verwendet wird, ohne die Unterfelder für die Gebotsstrategie festzulegen.

In diesem Fall wird mit den Methoden all_set_fields_of() und field_mask() des Dienstprogramms FieldMasks nicht das gewünschte Ziel erreicht.

Im folgenden Beispiel wird eine Feldmaske generiert, die maximize_conversions enthält. Die Google Ads API lässt dieses Verhalten jedoch nicht zu, um zu verhindern, dass Felder versehentlich gelöscht werden. Stattdessen wird der Fehler FieldMaskError.FIELD_HAS_SUBFIELDS ausgegeben.

Warnung: Der folgende Code führt zu einem Fehler.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new(),
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask includes 'maximize_conversions',
# which produces a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

# Sends the operation in a mutate request that results in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
  customerId => $customer_id,
  operations => [$campaign_operation],
});

Im folgenden Beispiel wird gezeigt, wie Sie eine Kampagne richtig aktualisieren, sodass die Gebotsstrategie MaximizeConversions verwendet wird, ohne die Unterfelder festzulegen.

**Erfolg** :Mit dem folgenden Code wird die Gebotsstrategie der Kampagne aktualisiert.

# Creates a campaign with the proper resource name.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
  });

# Creates a field mask from the existing campaign and adds the mutable subfield
# on the MaximizeConversions bidding strategy to the field mask. Because this
# field is included in the field mask but excluded from the campaign object,
# the Google Ads API sets the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# See the guide on assigning standard and portfolio bidding strategies
# (/google-ads/api/docs/campaigns/bidding/assign-strategies).
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => $field_mask,
  });

Felder löschen

Felder können explizit gelöscht werden, indem Sie sie der Feldmaske hinzufügen, wie im vorherigen Beispiel gezeigt, oder indem Sie das Feld auf einen leeren oder nicht definierten Wert setzen. Angenommen, Sie haben eine Kampagne, die die Gebotsstrategie MaximizeConversions verwendet, und das Feld target_cpa_micros ist auf einen Wert größer als 0 festgelegt.

**Erfolg** :Mit dem folgenden Code wird das Feld target_cpa_micros gelöscht.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new({
        targetCpaMicros => 0,
      }),
  });

# Constructs an operation using all_set_fields_of to derive the update mask,
# which includes 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

Felder mit verschachtelten Unterfeldern können nur gelöscht werden, indem Sie jedes der einzelnen Unterfelder löschen. Das wird unter Objektfelder mit definierten Unterfeldern gezeigt.