Thiết lập SDK IMA cho DAI

Tính năng Chèn quảng cáo động (DAI) để bắt đầu kiếm tiền từ luồng video nội dung của bạn bằng quảng cáo.

SDK IMA giúp bạn dễ dàng tích hợp quảng cáo đa phương tiện vào trang web và ứng dụng của mình. SDK IMA có thể yêu cầu quảng cáo từ bất kỳ máy chủ quảng cáo tuân thủ VAST nào và quản lý việc phát quảng cáo trong ứng dụng của bạn. Với SDK DAI của IMA, các ứng dụng sẽ đưa ra yêu cầu về luồng cho quảng cáo và video nội dung – có thể là nội dung VOD hoặc nội dung trực tiếp. Sau đó, SDK sẽ trả về một luồng video kết hợp, nhờ đó bạn không phải quản lý việc chuyển đổi giữa quảng cáo và video nội dung trong ứng dụng của mình.

Chọn giải pháp DAI mà bạn quan tâm

Dịch vụ đầy đủ Phân phát pod

Hướng dẫn này minh hoạ cách phát luồng phát trực tiếp hoặc luồng VOD Phân phát nhóm DAI bằng SDK IMA DAI cho Roku. Để xem hoặc làm theo một mẫu tích hợp đã hoàn tất, hãy tải ví dụ về việc phân phát nhóm video xuống.

Lưu ý: SDK IMA DAI cho Roku hỗ trợ cả luồng HLS và DASH mà không có sự khác biệt về cách triển khai.

Để sử dụng IMA DAI, bạn phải có tài khoản Ad Manager 360 nâng cao. Nếu bạn có tài khoản Ad Manager, hãy liên hệ với người quản lý tài khoản để biết thêm thông tin chi tiết. Để biết thông tin về cách đăng ký Ad Manager, hãy truy cập vào Trung tâm trợ giúp của Ad Manager.

Lưu ý: Để biết thông tin về cách tích hợp với các nền tảng khác hoặc cách sử dụng SDK phía máy khách IMA, hãy xem SDK Quảng cáo trên phương tiện truyền thông tương tác.

Tổng quan về cơ chế Phân phát nhóm DAI của IMA

Việc triển khai tính năng Phân phát nhóm bằng DAI của IMA bao gồm 2 thành phần SDK chính, được minh hoạ trong hướng dẫn này:

• StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest(): Tạo một đối tượng xác định yêu cầu truyền phát đến các máy chủ quảng cáo của Google. Các yêu cầu này chỉ định một Mã mạng, và Pod Live ima.StreamRequest cũng yêu cầu một Khoá tài sản tuỳ chỉnh và một khoá API không bắt buộc.
• StreamManager: Một đối tượng xử lý hoạt động giao tiếp giữa luồng video và SDK DAI của IMA, chẳng hạn như kích hoạt ping theo dõi và chuyển tiếp các sự kiện luồng đến nhà xuất bản.

Ngoài ra, bạn cần gửi yêu cầu đến máy chủ thao tác tệp kê khai để truy xuất tệp kê khai luồng nhằm hiển thị cho ứng dụng của bạn. Quy trình chính xác có thể khác nhau tuỳ theo đối tác công nghệ video (VTP).

Lưu ý quan trọng: Để phục vụ mục đích của hướng dẫn này, hãy giả định rằng máy chủ thao tác tệp kê khai mong đợi một yêu cầu GET có mã nhận dạng luồng được truyền dưới dạng một biến truy vấn. Sử dụng macro [[STREAMID]] làm phần giữ chỗ trong URL yêu cầu và thay thế bằng mã nhận dạng luồng trước khi đưa ra yêu cầu. Máy chủ thao tác tệp kê khai của bạn có thể khác.

Điều kiện tiên quyết

• Đọc kỹ trang về khả năng tương thích của chúng tôi để đảm bảo trường hợp sử dụng mà bạn dự định được hỗ trợ.
• Tải mã trình phát mẫu Roku của chúng tôi xuống.
• Triển khai mã trình phát mẫu cho một thiết bị Roku để xác minh rằng chế độ thiết lập phát triển của bạn đang hoạt động.

Phát video của bạn

Trình phát video mẫu được cung cấp sẽ phát một video nội dung ngay khi bạn mở hộp. Triển khai trình phát mẫu cho thiết bị Roku để đảm bảo bạn đã thiết lập môi trường phát triển đúng cách.

Biến trình phát video của bạn thành trình phát luồng DAI của IMA

Hãy làm theo các bước sau để triển khai trình phát trực tuyến.

Tạo Sdk.xml

Thêm một tệp mới vào dự án của bạn cùng với MainScene.xml có tên là Sdk.xml và thêm đoạn mã sau:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

Bạn cần chỉnh sửa cả hai tệp này (MainScene.xml và Sdk.xml) trong suốt hướng dẫn này.

Tải Khung SDK DAI của IMA

Để tải khung này, hãy thêm nội dung sau vào manifest và Sdk.xml:

manifest

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

Khởi chạy IMA DAI SDK

Bước đầu tiên để tải luồng Chèn quảng cáo động của IMA là tải và khởi chạy IMA DAI SDK. Sau đây là cách khởi chạy tập lệnh IMA DAI SDK.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

Bây giờ, hãy bắt đầu tác vụ này trong MainScene.xml và xoá lệnh gọi để tải luồng nội dung.

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

Tạo trình phát luồng IMA

Tiếp theo, bạn cần sử dụng roVideoScreen hiện có để tạo trình phát luồng IMA.

Phân phát nhóm quảng cáo trong sự kiện phát trực tiếp

Đối với sự kiện phát trực tiếp, trình phát trực tiếp này triển khai 3 phương thức gọi lại: streamInitialized, adBreakStarted và adBreakEnded.

Đồng thời, vô hiệu hoá tính năng tua khi luồng được tải. Điều này ngăn người dùng bỏ qua quảng cáo đầu video ngay khi quảng cáo bắt đầu, trước khi sự kiện ad break started được kích hoạt.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

Phân phát nhóm luồng VOD

Đối với luồng VOD, trình phát luồng này triển khai 4 phương thức gọi lại: streamInitialized, loadUrl, adBreakStarted và adBreakEnded. Trong lệnh gọi lại streamInitialized, hãy nhớ gọi StreamManager.loadThirdPartyStream(). Nếu bạn không làm như vậy, SDK sẽ không kích hoạt hàm loadUrl.

Trong bước này, bạn cũng yêu cầu đối tác công nghệ video (VTP) cung cấp URL phát trực tiếp kèm theo mã nhận dạng luồng phát mà bạn nhận được ở bước loadAdPodStream(). Sau đó, hãy gọi StreamManager.loadThirdPartyStream() bằng tệp kê khai nhóm quảng cáo và mọi phụ đề do VTP của bạn trả về.

Đồng thời, vô hiệu hoá tính năng tua khi luồng được tải. Điều này ngăn người dùng bỏ qua quảng cáo đầu video ngay khi quảng cáo bắt đầu, trước khi sự kiện ad break started được kích hoạt.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

Tạo và thực thi yêu cầu phát trực tiếp hoặc yêu cầu phân phát nhóm VOD

Sau khi có trình phát trực tuyến, bạn có thể tạo và thực thi một yêu cầu phát trực tuyến. Ví dụ này có dữ liệu cho một luồng Pod Serving được lưu trữ trong m.testPodServingStream.

Phân phát nhóm quảng cáo trong sự kiện phát trực tiếp

Trong đối tượng m.testPodServingStream, hãy lưu trữ các tham số mà Google Ad Manager cần để xác định luồng phát được đề cập, chẳng hạn như mã mạng và khoá tài sản tuỳ chỉnh. Ngoài ra, hãy lưu trữ URL tệp kê khai dùng để truy cập vào máy chủ thao tác tệp kê khai. Trong trường hợp này, URL tệp kê khai cần có mã nhận dạng luồng phát của Google được thêm vào sau khi yêu cầu luồng phát được trả về.

Để có thể hỗ trợ AdUI, chẳng hạn như biểu tượng Lựa chọn quảng cáo, bạn cũng phải truyền một tham chiếu đến nút chứa video nội dung của mình trong yêu cầu.

Lưu ý: Các thông số luồng được cung cấp là dành cho luồng Live pod. Để kiểm thử bằng luồng nhóm VOD, bạn cần cung cấp các tham số luồng kiểm thử của riêng mình.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

Phân phát nhóm luồng VOD

Trong đối tượng m.testPodServingStream, bạn sẽ lưu trữ mã mạng được dùng trong yêu cầu phát trực tuyến, để Google Ad Manager có thể cung cấp một mã nhận dạng luồng phát. Ngoài ra, hãy lưu trữ URL tệp kê khai dùng để truy cập vào tệp kê khai dành riêng cho người dùng trên máy chủ thao tác tệp kê khai.

Để có thể hỗ trợ AdUI (chẳng hạn như biểu tượng Lựa chọn quảng cáo), bạn cũng phải truyền một tham chiếu đến nút chứa video nội dung của bạn trong yêu cầu.

Lưu ý: Bạn sẽ cần cung cấp mã mạng và URL tệp kê khai của riêng mình để kiểm thử việc triển khai luồng VOD.

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

Thêm trình nghe sự kiện và bắt đầu luồng

Phân phát nhóm quảng cáo trong sự kiện phát trực tiếp

Sau khi yêu cầu luồng phát, bạn chỉ cần làm thêm một vài việc: thêm trình nghe sự kiện để theo dõi tiến trình quảng cáo và chuyển tiếp thông báo Roku đến SDK. Bạn phải chuyển tiếp tất cả thông báo đến SDK để đảm bảo quảng cáo phát chính xác. Nếu không, số lượt xem quảng cáo sẽ được báo cáo không chính xác.

Ở bước này, bạn cũng sẽ thêm một hàm để thay thế macro [[STREAMID]] bằng mã nhận dạng luồng phát và truyền URL yêu cầu tệp kê khai đã hoàn tất đến trình phát video. Lần triển khai này sẽ lấy mã nhận dạng luồng trong bước này, nhưng tuỳ thuộc vào việc tích hợp VTP, mã nhận dạng này có thể có sẵn trước bước này.

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

Phân phát nhóm luồng VOD

Sau khi yêu cầu luồng phát, bạn chỉ cần làm thêm một vài việc: thêm trình nghe sự kiện để theo dõi tiến trình quảng cáo và chuyển tiếp thông báo Roku đến SDK. Bạn cần chuyển tiếp tất cả thông báo đến SDK để đảm bảo quảng cáo phát chính xác. Nếu bạn không làm như vậy, số lượt xem quảng cáo sẽ được báo cáo không chính xác.

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub