DAI-এর জন্য IMA SDK সেট-আপ করা

প্ল্যাটফর্ম বেছে নিন: HTML5 Android iOS tvOS Cast Roku

IMA SDK আপনার ওয়েবসাইট ও অ্যাপে মাল্টিমিডিয়া বিজ্ঞাপন ইন্টিগ্রেট করা সহজ করে তোলে। IMA SDK যেকোনও VAST-এর সাথে মানানসই বিজ্ঞাপন সার্ভার থেকে বিজ্ঞাপনের অনুরোধ করতে এবং আপনার অ্যাপে বিজ্ঞাপন প্লেব্যাক ম্যানেজ করতে পারে। IMA DAI SDK-এর মাধ্যমে, অ্যাপগুলি বিজ্ঞাপন ও কন্টেন্ট ভিডিওর জন্য—VOD বা লাইভ কন্টেন্ট— স্ট্রিম অনুরোধ করে। SDK তারপর একটি সম্মিলিত ভিডিও স্ট্রিম ফেরত পাঠায়, যাতে আপনাকে অ্যাপের মধ্যে বিজ্ঞাপন ও কন্টেন্ট ভিডিওর মধ্যে পরিবর্তন ম্যানেজ করতে না হয়।

আপনি যে DAI সমাধানে আগ্রহী সেটি বেছে নিন

সম্পূর্ণ পরিষেবা পড পরিবেশন

সম্পূর্ণ পরিষেবা DAI

এই নির্দেশিকা থেকে আপনি জানতে পারবেন যে কীভাবে ভিডিও প্লেয়ার অ্যাপে IMA DAI SDK ইন্টিগ্রেট করতে হয়। আপনি যদি সম্পূর্ণ স্যাম্পেল ইন্টিগ্রেশন দেখতে বা অনুসরণ করতে চান, তাহলে GitHub থেকে প্রাথমিক উদাহরণ ডাউনলোড করুন।

মনে রাখবেন: Roku-এর জন্য IMA DAI SDK, HLS ও DASH, দু'টি স্ট্রিমেই কাজ করে এবং দু'টির মধ্যে কোনও পার্থক্য নেই।

IMA DAI ব্যবহার করতে হলে, আপনার কাছে অবশ্যই Ad Manager 360 Advanced অ্যাকাউন্ট থাকতে হবে। আপনার Ad Manager অ্যাকাউন্ট থাকলে, আরও বিবরণের জন্য আপনার অ্যাকাউন্ট ম্যানেজারের সাথে যোগাযোগ করুন। Ad Manager-এ সাইন-আপ করা সম্পর্কে তথ্য পেতে, এখানে যান: Ad Manager সহায়তা কেন্দ্র।

মনে রাখবেন: অন্যান্য প্ল্যাটফর্মের সাথে ইন্টিগ্রেট করা বা IMA ক্লায়েন্ট-সাইড SDK ব্যবহার করা সম্পর্কিত তথ্যের জন্য, Interactive Media Ads SDK দেখুন।

IMA DAI ওভারভিউ

IMA DAI প্রয়োগ করার জন্য দুটি প্রধান SDK কম্পোনেন্ট প্রয়োজন হয়, যা এই নির্দেশিকায় দেখানো হয়েছে:

• StreamRequest: স্ট্রিম অনুরোধকে সংজ্ঞায়িত করে এমন একটি অবজেক্ট। স্ট্রিম করার অনুরোধ চাহিদা অনুযায়ী ভিডিও বা লাইভ স্ট্রিমের জন্য করা হতে পারে। লাইভ স্ট্রিম অনুরোধে অ্যাসেট কী উল্লেখ করা থাকে, যেখানে VOD অনুরোধে CMS আইডি ও ভিডিও আইডি উল্লেখ করা থাকে। দুটি অনুরোধের ধরনের মধ্যে নির্দিষ্ট স্ট্রিম অ্যাক্সেস করার জন্য প্রয়োজনীয় API কী এবং Google Ad Manager সেটিংস অনুযায়ী IMA SDK-এর বিজ্ঞাপন শনাক্তকারী ম্যানেজ করার জন্য Google Ad Manager নেটওয়ার্ক কোড ঐচ্ছিকভাবে অন্তর্ভুক্ত থাকতে পারে।
• StreamManager: DAI ব্যাকএন্ডের সাথে ডায়নামিক বিজ্ঞাপন যোগ করার স্ট্রিম ও ইন্টার‍্যাকশন ম্যানেজ করে এমন একটি অবজেক্ট। এছাড়াও, স্ট্রিম ম্যানেজার ট্র্যাকিং পিং ম্যানেজ করে এবং স্ট্রিম ও বিজ্ঞাপন ইভেন্ট প্রকাশকের কাছে ফরওয়ার্ড করে।

পূর্বশর্ত

• আপনার উদ্দেশ্যপূর্ণ ব্যবহারের ক্ষেত্রে কাজ করে কিনা তা নিশ্চিত করতে আমাদের মানানসই পৃষ্ঠা পড়ুন।
• আমাদের Roku স্যাম্পেল প্লেয়ার কোড ডাউনলোড করুন
• আপনার ডেভেলপমেন্ট সেট-আপ কাজ করছে কিনা তা যাচাই করতে Roku ডিভাইসে স্যাম্পেল প্লেয়ার কোড ডেপ্লয় করুন।

আপনার ভিডিও চালান

প্রদান করা স্যাম্পেল ভিডিও প্লেয়ারটি বক্সের বাইরে থাকা কন্টেন্ট ভিডিও চালায়। আপনার ডেভেলপমেন্ট এনভায়রনমেন্ট সঠিকভাবে সেট-আপ করা হয়েছে কিনা তা নিশ্চিত করতে, আপনার Roku প্লেয়ারে স্যাম্পেল প্লেয়ার ডিপ্লয় করুন।

আপনার ভিডিও প্লেয়ারকে IMA DAI স্ট্রিম প্লেয়ারে পরিবর্তন করা

স্ট্রিম প্লেয়ার প্রয়োগ করতে এইসব ধাপ অনুসরণ করুন।

Sdk.xml তৈরি করা

MainScene.xml-এর পাশাপাশি আপনার প্রোজেক্টে Sdk.xml নামের একটি নতুন ফাইল যোগ করুন, এবং নিম্নলিখিত বয়লারপ্লেট যোগ করুন:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
  ' Your code goes here.
]]>
</script>
</component>

এই সম্পূর্ণ গাইড জুড়ে আপনাকে এই দুটি ফাইলই এডিট করতে হবে।

Roku Advertising Framework লোড করুন

IMA DAI SDK, Roku Advertising Framework-এর উপর নির্ভর করে। ফ্রেমওয়ার্ক লোড করতে, manifest এবং Sdk.xml-এ নিম্নলিখিতগুলি যোগ করুন:

bs_libs_required=roku_ads_lib,googleima3
manifest

Library "Roku_Ads.brs"
Library "IMA3.brs"
Sdk.xml

IMA DAI SDK লোড করা

IMA DAI SDK লোড করতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

1. New_IMASDK() কল দিয়ে IMA SDK চালু করুন:

   sub loadSdk()
     If m.sdk = invalid
       m.sdk = New_IMASDK()
     End If
     m.top.sdkLoaded = true
   End Sub
   Sdk.xml
   

2. IMA লোড হয়েছে কিনা তা ট্র্যাক করতে sdkLoaded বুলিয়ান ফিল্ড তৈরি করুন:

   <field id="sdkLoaded" type="Boolean" />
   Sdk.xml
   

3. প্রধান runThread() সাবরুটিন থেকে loadSdk() সাবরুটিন কল করুন:

   if not m.top.sdkLoaded
     loadSdk()
   End If
   Sdk.xml
   

4. sdkTask অবজেক্ট তৈরি ও রান করাতে MainScene.xml-এ loadImaSdk() ফাংশন তৈরি করুন:

   function loadImaSdk() as void
     m.sdkTask = createObject("roSGNode", "imasdk")
     m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
     m.sdkTask.observeField("errors", "onSdkLoadedError")
   
     ' Change to m.testLiveStream to demo live instead of VOD.
     selectedStream = m.testVodStream
     m.videoTitle = selectedStream.title
     m.sdkTask.streamData = selectedStream
   
     m.sdkTask.observeField("urlData", "urlLoadRequested")
     m.sdkTask.video = m.video
     ' Setting control to run starts the task thread.
     m.sdkTask.control = "RUN"
   end function
   MainScene.xml
   

5. init() ফাংশন থেকে loadImaSdk() ফাংশন কল করুন।

6. SDK লোড ইভেন্টের উত্তর দিতে onSdkLoaded() এবং onSdkLoadedError() লিসনার সাবরুটিন তৈরি করুন:

   Sub onSdkLoaded(message as Object)
     print "----- onSdkLoaded --- control ";message
   End Sub
   
   Sub onSdkLoadedError(message as Object)
     print "----- errors in the sdk loading process --- ";message
   End Sub
   MainScene.xml
   

IMA স্ট্রিম প্লেয়ার তৈরি করা

IMA স্ট্রিম প্লেয়ার তৈরি করতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

1. একটি setupVideoPlayer() সাবরুটিন তৈরি করুন যা নিম্নলিখিত কাজগুলি করে:

   1. স্ট্রিম প্লেয়ার তৈরি করতে createPlayer() পদ্ধতি ব্যবহার করুন।

   2. ওই স্ট্রিম প্লেয়ারে তিনটি কলব্যাক পদ্ধতি প্রয়োগ করুন: loadUrl, adBreakStarted ও adBreakEnded।

   3. স্ট্রিম লোড করা হলে, 'ট্রিক প্লে' বন্ধ করে দিন। এটি ব্যবহারকারীদের বিজ্ঞাপন বিরতি শুরু হওয়ার ইভেন্ট ফায়ার হওয়ার আগে, স্ট্রিম শুরু হওয়ার সাথে সাথেই প্রি-রোল এড়িয়ে যাওয়া থেকে আটকায়।

   sub setupVideoPlayer()
     sdk = m.sdk
     m.player = sdk.createPlayer()
     m.player.top = m.top
     m.player.loadUrl = Function(urlData)
       ' This line prevents users from scanning during buffering
       ' or during the first second of the ad before we have a callback from roku.
       ' If there are no prerolls disabling trickplay isn't needed.
       m.top.video.enableTrickPlay = false
       m.top.urlData = urlData
     End Function
     m.player.adBreakStarted = Function(adBreakInfo as Object)
       print "---- Ad Break Started ---- "
       m.top.adPlaying = True
       m.top.video.enableTrickPlay = false
     End Function
     m.player.adBreakEnded = Function(adBreakInfo as Object)
       print "---- Ad Break Ended ---- "
       m.top.adPlaying = False
       m.top.video.enableTrickPlay = true
     End Function
     m.player.seek = Function(timeSeconds as Double)
       print "---- SDK requested seek to ----" ; timeSeconds
       m.top.video.seekMode = "accurate"
       m.top.video.seek = timeSeconds
     End Function
   End Sub
   Sdk.xml
   

   এড়িয়ে যাওয়া যায় এমন বিজ্ঞাপন কাজ করার জন্য seek কলব্যাক পদ্ধতি যোগ করুন। আরও বিবরণের জন্য, এড়িয়ে যাওয়ার মতো বিজ্ঞাপন যোগ করা দেখুন।

2. setupVideoPlayer() সাবরুটিনে ব্যবহৃত urlData, adPlaying ও video ফিল্ড যোগ করুন:

   <field id="urlData" type="assocarray" />
   <field id="adPlaying" type="Boolean" />
   <field id="video" type="Node" />
   Sdk.xml
   

স্ট্রিম করার অনুরোধ তৈরি ও প্রয়োগ করা

আপনার DAI স্ট্রিমের অনুরোধ করতে, নিম্নলিখিত কাজগুলি করুন:

1. স্ট্রিম তৈরি ও অনুরোধ করার জন্য loadStream() সাবরুটিন তৈরি করুন। বিজ্ঞাপন UI-কে সাপোর্ট করতে, যেমন adChoices আইকন, আপনাকে অবশ্যই আপনার অনুরোধের অংশ হিসেবে আপনার কন্টেন্ট ভিডিও থাকা নোডের রেফারেন্সও পাস করতে হবে:

   Sub loadStream()
     sdk = m.sdk
     sdk.initSdk()
     setupVideoPlayer()
   
     request = {}
     streamData = m.top.streamData
     if streamData.type = "live"
       request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey, streamData.networkCode)
     else if streamData.type = "vod"
       request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey, streamData.networkCode)
     else
       request = sdk.CreateStreamRequest()
     end if
   
     request.player = m.player
     request.adUiNode = m.top.video
   
     requestResult = sdk.requestStream(request)
     If requestResult <> Invalid
       print "Error requesting stream ";requestResult
     Else
       m.streamManager = Invalid
       While m.streamManager = Invalid
         sleep(50)
         m.streamManager = sdk.getStreamManager()
       End While
       If m.streamManager = Invalid or m.streamManager["type"] <> Invalid or m.streamManager["type"] = "error"
         errors = CreateObject("roArray", 1, True)
         print "error ";m.streamManager["info"]
         errors.push(m.streamManager["info"])
         m.top.errors = errors
       Else
         m.top.streamManagerReady = True
         addCallbacks()
         m.streamManager.start()
       End If
     End If
   End Sub
   Sdk.xml
   

2. loadStream() সাবরুটিনে ব্যবহার করা streamData এবং streamManagerReady ফিল্ড যোগ করুন:

   <field id="streamManagerReady" type="Boolean" />
   <field id="streamData" type="assocarray" />
   Sdk.xml
   

3. স্ট্রিম ম্যানেজার উপলভ্য না থাকলে, runThread() সাবরুটিন থেকে loadStream() সাবরুটিন কল করুন:

   if not m.top.streamManagerReady
     loadStream()
   End If
   Sdk.xml
   

4. VOD বা লাইভ স্ট্রিমের মধ্যে থেকে একটি বেছে নিন। নিচের উদাহরণে লাইভস্ট্রিম ও VOD স্ট্রিমের জন্য স্ট্রিম প্যারামিটার রয়েছে:

   m.testLiveStream = {
     title: "Live Stream",
     assetKey: "c-rArva4ShKVIAkNfy6HUQ",
     networkCode: "21775744923",
     apiKey: "",
     type: "live"
   }
   m.testVodStream = {
     title: "VOD stream"
     contentSourceId: "2548831",
     videoId: "tears-of-steel",
     networkCode: "21775744923",
     apiKey: "",
     type: "vod"
   }
   MainScene.xml
   

   ডিফল্ট হিসেবে, এই গাইড VOD স্ট্রিম ব্যবহার করে। আপনি m.testVodStream অবজেক্ট থেকে m.testLiveStream অবজেক্টে selectedStream ভেরিয়েবল পরিবর্তন করে পরিবর্তে লাইভ স্ট্রিম ব্যবহার করতে পারবেন।

স্ট্রিম শুরু করা

স্ট্রিম ডেটা শোনার জন্য urlLoadRequested() সাবরুটিন তৈরি করুন এবং playStream() সাবরুটিন কল করুন:

Sub urlLoadRequested(message as Object)
  print "Url Load Requested ";message
  data = message.getData()

  playStream(data.manifest, data.format)
End Sub
MainScene.xml

স্ট্রিম প্লেব্যাক শুরু করতে playStream() তৈরি করুন:

Sub playStream(url as String, format as String)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.videoTitle
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
End Sub
MainScene.xml

স্ট্রিম মেটাডেটার জন্য শুনুন

স্ট্রিম প্লেব্যাকের সময় চালানোর জন্য while লুপ সহ runLoop() সাবরুটিন তৈরি করুন এবং StreamManager.onMessage() ব্যবহার করে IMA-তে স্ট্রিম মেটাডেটা পাঠান:

গুরুত্বপূর্ণ: বিজ্ঞাপন যাতে সঠিকভাবে প্লেব্যাক করা যায় তা নিশ্চিত করতে আপনাকে অবশ্যই SDK-তে সব মেসেজ ফরওয়ার্ড করতে হবে।

Sub runLoop()
  ' Forward all timed metadata events.
  m.top.video.timedMetaDataSelectionKeys = ["*"]

  ' Cycle through all the fields and just listen to them all.
  m.port = CreateObject("roMessagePort")
  fields = m.top.video.getFields()
  for each field in fields
    m.top.video.observeField(field, m.port)
  end for

  while True
    msg = wait(1000, m.port)
    if m.top.video = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.video.position
    ' Only enable trickplay after a few seconds, in case we start with an ad,
    ' to prevent users from skipping through that ad.
    If currentTime > 3 And not m.top.adPlaying
       m.top.video.enableTrickPlay = true
    End If
  end while
End Sub
Sdk.xml

বিজ্ঞাপন ইভেন্ট শোনা

আপনি যেহেতু IMA-তে স্ট্রিম মেটাডেটা পাস করছেন, তাই IMA বিজ্ঞাপন বিরতির সময় বিজ্ঞাপন ইভেন্ট এমিট করতে পারবে। বিজ্ঞাপন ইভেন্টের উত্তর দেওয়ার জন্য প্রয়োজন অনুযায়ী বিজ্ঞাপন ইভেন্ট লিসনার তৈরি করুন:

Function addCallbacks() as Void
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function

Function startCallback(ad as Object) as Void
  print "Callback from SDK -- Start called - "
End Function

Function firstQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- First quartile called - "
End Function

Function midpointCallback(ad as Object) as Void
  print "Callback from SDK -- Midpoint called - "
End Function

Function thirdQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- Third quartile called - "
End Function

Function completeCallback(ad as Object) as Void
  print "Callback from SDK -- Complete called - "
End Function

Function errorCallback(error as Object) as Void
  print "Callback from SDK -- Error called - "; error
  ' errors are critical and should terminate the stream.
  m.errorState = True
End Function
Sdk.xml

স্কিপ করা যায় এমন বিজ্ঞাপন যোগ করুন (ঐচ্ছিক)

এড়িয়ে যাওয়ার মতো বিজ্ঞাপন কাজ করানোর জন্য, আপনাকে IMA DAI SDK-এর প্লেয়ার অবজেক্টে একটি seekমেথড যোগ করতে হবে যা ফ্লোটিং-পয়েন্ট সেকেন্ডে ভিডিওটিকে নির্দিষ্ট লোকেশনে প্রোগ্রামমেটিক উপায়ে নিয়ে যায়।

এড়িয়ে যাওয়ার মতো বিজ্ঞাপন যাতে কাজ করে, তার জন্য আপনাকে অনুরোধে adUiNode সেট করেছেন কিনা তা নিশ্চিত করতে হবে।

m.player.seek = Function(timeSeconds as Double)
  print "---- SDK requested seek to ----" ; timeSeconds
  m.top.video.seekMode = "accurate"
  m.top.video.seek = timeSeconds
End Function
Sdk.xml