DAI-এর জন্য IMA SDK সেট-আপ করা

প্ল্যাটফর্ম বেছে নিন: HTML5 Android iOS tvOS Cast Roku

IMA SDK আপনার ওয়েবসাইট ও অ্যাপে মাল্টিমিডিয়া বিজ্ঞাপন ইন্টিগ্রেট করা সহজ করে তোলে। IMA SDK যেকোনও VAST-এর সাথে মানানসই বিজ্ঞাপন সার্ভার থেকে বিজ্ঞাপনের অনুরোধ করতে এবং আপনার অ্যাপে বিজ্ঞাপন প্লেব্যাক ম্যানেজ করতে পারে। IMA DAI SDK-এর মাধ্যমে, অ্যাপগুলি বিজ্ঞাপন ও কন্টেন্ট ভিডিওর জন্য—VOD বা লাইভ কন্টেন্ট— স্ট্রিম অনুরোধ করে। SDK তারপর একটি সম্মিলিত ভিডিও স্ট্রিম ফেরত পাঠায়, যাতে আপনাকে অ্যাপের মধ্যে বিজ্ঞাপন ও কন্টেন্ট ভিডিওর মধ্যে পরিবর্তন ম্যানেজ করতে না হয়।

আপনি যে DAI সমাধানে আগ্রহী সেটি বেছে নিন

Roku-এর জন্য IMA DAI SDK ব্যবহার করে কীভাবে DAI পড পরিবেশন লাইভ বা VOD স্ট্রিম চালাতে হয়, এই নির্দেশিকা তা দেখায়। সম্পূর্ণ নমুনা ইন্টিগ্রেশন দেখতে বা ফলো করতে, পড পরিবেশনের উদাহরণ ডাউনলোড করুন।

IMA DAI পড পরিবেশন সংক্রান্ত ওভারভিউ

IMA DAI ব্যবহার করে পড পরিবেশন করার জন্য দুটি প্রধান SDK কম্পোনেন্ট প্রয়োগ করতে হয়, যা এই নির্দেশিকায় দেখানো হয়েছে:

  • StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest(): এমন একটি অবজেক্ট তৈরি করে যা Google-এর বিজ্ঞাপন সার্ভারে স্ট্রিম অনুরোধকে সংজ্ঞায়িত করে। এইসব অনুরোধে একটি নেটওয়ার্ক কোড উল্লেখ করা থাকে এবং Pod Live ima.StreamRequest-এর জন্য একটি কাস্টম অ্যাসেট কী এবং ঐচ্ছিক API কী-এরও প্রয়োজন হয়।
  • StreamManager: ভিডিও স্ট্রিম ও IMA DAI SDK-এর মধ্যে যোগাযোগ ম্যানেজ করে এমন একটি অবজেক্ট, যেমন ট্র্যাকিং পিং ফায়ার করা এবং প্রকাশককে স্ট্রিম ইভেন্ট ফরওয়ার্ড করা।

এছাড়াও, আপনার অ্যাপে দেখানোর জন্য স্ট্রিম ম্যানিফেস্ট পেতে, আপনাকে ম্যানিফেস্ট ম্যানিপুলেশন সার্ভার-এ অনুরোধ করতে হবে। ভিডিও টেকনোলজি পার্টনার (VTP) থেকে VTP-তে সঠিক প্রসেস আলাদা হতে পারে।

পূর্বশর্ত

  • আপনার উদ্দেশ্যপূর্ণ ব্যবহারের ক্ষেত্রে কাজ করে কিনা তা নিশ্চিত করতে আমাদের মানানসই পৃষ্ঠা ভাল করে পড়ে দেখুন।
  • আমাদের Roku স্যাম্পেল প্লেয়ার কোড ডাউনলোড করুন।
  • আপনার ডেভেলপমেন্ট সেট-আপ কাজ করছে কিনা তা যাচাই করতে, Roku ডিভাইসে স্যাম্পেল প্লেয়ার কোডটি ডেপ্লয় করুন।

আপনার ভিডিও চালান

প্রদান করা স্যাম্পেল ভিডিও প্লেয়ার বক্সের বাইরে থাকা কন্টেন্ট ভিডিও চালায়। আপনার ডেভেলপমেন্ট এনভায়রনমেন্ট সঠিকভাবে সেট-আপ করা হয়েছে কিনা তা নিশ্চিত করতে, আপনার Roku ডিভাইসে স্যাম্পেল প্লেয়ার ডেপ্লয় করুন।

আপনার ভিডিও প্লেয়ারকে IMA DAI স্ট্রিম প্লেয়ারে পরিবর্তন করুন

স্ট্রিম প্লেয়ার প্রয়োগ করতে এইসব ধাপ অনুসরণ করুন।

Sdk.xml তৈরি করা

MainScene.xml-এর পাশাপাশি আপনার প্রোজেক্টে Sdk.xml নামে একটি নতুন ফাইল যোগ করুন এবং নিম্নলিখিত বয়লারপ্লেট যোগ করুন:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

এই নির্দেশিকা জুড়ে আপনাকে এই দুটি ফাইল (MainScene.xml এবং Sdk.xml) এডিট করতে হবে।

IMA DAI SDK ফ্রেমওয়ার্ক লোড করা

ফ্রেমওয়ার্ক লোড করতে, manifest এবং Sdk.xml-এ নিম্নলিখিতগুলি যোগ করুন:

ম্যানিফেস্ট

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

IMA DAI SDK ইনিশিয়ালাইজ করা

আপনার IMA ডায়নামিক বিজ্ঞাপন যোগ করার স্ট্রিম লোড করার প্রথম ধাপ হল IMA DAI SDK লোড ও ইনিশিয়ালাইজ করা। নিম্নলিখিত কোড IMA DAI SDK স্ক্রিপ্ট ইনিশিয়ালাইজ করে।

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

এখন MainScene.xml-এ এই টাস্ক শুরু করুন এবং কন্টেন্ট লোড করার কল সরিয়ে দিন স্ট্রিম করুন।

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

IMA স্ট্রিম প্লেয়ার তৈরি করা

এর পরে, IMA স্ট্রিম প্লেয়ার তৈরি করতে আপনাকে নিজের বর্তমান roVideoScreen ব্যবহার করতে হবে।

লাইভ স্ট্রিম পড পরিবেশন করা

লাইভ স্ট্রিমের জন্য, এই স্ট্রিম প্লেয়ার তিনটি কলব্যাক পদ্ধতি প্রয়োগ করে: streamInitialized, adBreakStarted এবং adBreakEnded।

এছাড়াও, স্ট্রিম লোড হয়ে গেলে 'ট্রিক প্লে' ফিচার বন্ধ করে দেয়। এটি ব্যবহারকারীদেরকে বিজ্ঞাপন বিরতি শুরু হওয়ার আগে, প্রি-রোল শুরু হওয়ার সাথে সাথেই সেটি এড়িয়ে যাওয়া থেকে আটকায়।

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

VOD স্ট্রিম পড পরিবেশন করা

VOD স্ট্রিমের জন্য, এই স্ট্রিম প্লেয়ার চারটি কলব্যাক পদ্ধতি প্রয়োগ করে: streamInitialized, loadUrl, adBreakStarted এবং adBreakEnded। streamInitialized কলব্যাকে, StreamManager.loadThirdPartyStream() কল করতে ভুলবেন না। এটি না করলে SDK loadUrl ফাংশন ট্রিগার করবে না।

এই ধাপে, আপনি loadAdPodStream()-এ প্রাপ্ত স্ট্রিম আইডি সহ আপনার ভিডিও প্রযুক্তি পার্টনারের (VTP) কাছ থেকে একটি স্ট্রিম URL-এর জন্য অনুরোধ করেন। তারপরে, বিজ্ঞাপন পড ম্যানিফেস্ট এবং আপনার VTP-এর প্রদান করা যেকোনও সাবটাইটেল সহ StreamManager.loadThirdPartyStream() কল করুন।

এছাড়াও, স্ট্রিম লোড হয়ে গেলে 'ট্রিক প্লে' ফিচার বন্ধ করে দেয়। এটি ব্যবহারকারীদের বিজ্ঞাপন বিরতি শুরু হওয়ার ইভেন্ট ফায়ার হওয়ার আগে, প্রি-রোল শুরু হওয়ার সাথে সাথেই সেটি এড়িয়ে যেতে বাধা দেয়।

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

লাইভ বা VOD পড সার্ভিং স্ট্রিম অনুরোধ তৈরি ও প্রয়োগ করা

আপনার কাছে স্ট্রিম প্লেয়ার থাকলে, আপনি স্ট্রিম অনুরোধ তৈরি ও এক্সিকিউট করতে পারবেন। এই উদাহরণে, পড পরিবেশনকারী স্ট্রিমের ডেটা m.testPodServingStream-এ সেভ করা আছে।

লাইভ স্ট্রিম পড পরিবেশন করা

m.testPodServingStream অবজেক্টে, Google Ad Manager-কে প্রশ্ন করা স্ট্রিম শনাক্ত করতে প্রয়োজনীয় প্যারামিটার স্টোর করুন, যেমন নেটওয়ার্ক কোড ও কাস্টম অ্যাসেট কী। এছাড়াও, আপনার ম্যানিফেস্ট ম্যানিপুলেশন সার্ভার অ্যাক্সেস করতে ব্যবহৃত ম্যানিফেস্ট URL স্টোর করুন। এই ক্ষেত্রে, স্ট্রিম অনুরোধ ফেরত দেওয়ার পরে ম্যানিফেস্ট URL-এ Google স্ট্রিম আইডি যোগ করতে হবে।

adChoices আইকনের মতো AdUI কাজ করে তা নিশ্চিত করতে, আপনাকে অবশ্যই আপনার অনুরোধের অংশ হিসেবে আপনার কন্টেন্ট ভিডিও থাকা নোডের রেফারেন্স পাস করতে হবে।

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

VOD স্ট্রিম পড পরিষেবা

m.testPodServingStream অবজেক্টে, আপনি স্ট্রিম অনুরোধে ব্যবহৃত নেটওয়ার্ক কোড স্টোর করবেন, যাতে Google Ad Manager একটি স্ট্রিম আইডি প্রদান করতে পারে। এছাড়াও, আপনার ম্যানিপুলেশন সার্ভারে ব্যবহারকারী-নির্দিষ্ট ম্যানিফেস্ট অ্যাক্সেস করতে ব্যবহৃত ম্যানিফেস্ট URL সেভ করুন।

AdChoices আইকনের মতো AdUI-এর সুবিধা দিতে, আপনার অনুরোধের অংশ হিসেবে কন্টেন্ট ভিডিও সহ নোডের রেফারেন্সও পাস করতে হবে।

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

ইভেন্ট লিসনার যোগ করে স্ট্রিম শুরু করা

লাইভ স্ট্রিম পড পরিবেশন করা

আপনার স্ট্রিমের অনুরোধ করার পরে, শুধুমাত্র কয়েকটি জিনিস করার বাকি থাকে: বিজ্ঞাপনের অগ্রগতি ট্র্যাক করতে ইভেন্ট লিসনার যোগ করুন এবং SDK-তে Roku মেসেজ ফরওয়ার্ড করুন। বিজ্ঞাপন যাতে সঠিকভাবে প্লেব্যাক হয় তা নিশ্চিত করতে, SDK-তে সব মেসেজ ফরওয়ার্ড করা গুরুত্বপূর্ণ। এটি না করলে, বিজ্ঞাপন ভিউ অনুপযুক্তভাবে রিপোর্ট করা হয়।

এই ধাপে, আপনি [[STREAMID]] ম্যাক্রোকে স্ট্রিম আইডির সাথে পরিবর্তন করার জন্য একটি ফাংশন যোগ করেন এবং সম্পূর্ণ ম্যানিফেস্ট অনুরোধ URL ভিডিও প্লেয়ারে পাস করেন। এই প্রয়োগের মাধ্যমে এই ধাপে স্ট্রিম আইডি পাওয়া যায়, তবে আপনার VTP ইন্টিগ্রেশনের উপর নির্ভর করে, এটি এই ধাপের আগেও উপলভ্য হতে পারে।

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

VOD স্ট্রিম পড পরিবেশন করা

আপনার স্ট্রিমের জন্য অনুরোধ করার পরে, শুধুমাত্র কয়েকটি জিনিস বাকি আছে: বিজ্ঞাপনের প্রগ্রেস ট্র্যাক করতে এবং Roku মেসেজ SDK-তে ফরওয়ার্ড করতে ইভেন্ট লিসেনার যোগ করুন। বিজ্ঞাপন সঠিকভাবে প্লেব্যাক করার জন্য SDK-তে সব মেসেজ ফরওয়ার্ড করা গুরুত্বপূর্ণ। এটি না করলে, বিজ্ঞাপন ভিউয়ের ব্যাপারে ভুল রিপোর্ট করা হবে।

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub