Merchant Center क्वेरी लैंग्वेज का व्याकरण

Merchant Center क्वेरी लैंग्वेज के व्याकरण का रेफ़रंस (रेगुलर एक्सप्रेशन नोटेशन में) यहां दिया गया है:

Query            -> SelectClause FromClause? WhereClause? OrderByClause? LimitClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM TableName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger

Condition        -> FieldName Operator Value | FieldName BETWEEN Value AND Value
Operator         -> = | != | > | >= | < | <= | <> | IN | NOT IN |
                    CONTAINS ANY | CONTAINS ALL | CONTAINS NONE | DURING |
                    LIKE | NOT LIKE | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Number | NumberList | String | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
TableName        -> [A-Z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ?से किसी वैकल्पिक एलिमेंट के बारे में पता चलता है.
  • * का मतलब शून्य या उससे ज़्यादा है; + का मतलब एक या उससे ज़्यादा है.
  • (xxxxxx) किसी ग्रुपिंग को दिखाता है.
  • [a-z0-9], कैरेक्टर की रेंज दिखाता है.
  • | का मतलब "या" है.
पीछे जाएं
खास जानकारी
आगे बढ़ें
क्वेरी स्ट्रक्चर