Bắt đầu sử dụng SDK IMA DAI

SDK IMA giúp bạn dễ dàng tích hợp quảng cáo đa phương tiện vào trang web và ứng dụng của mình. SDK IMA có thể yêu cầu quảng cáo từ bất kỳ Máy chủ quảng cáo tuân thủ VAST và quản lý việc phát quảng cáo trong các ứng dụng của bạn. Với SDK IMA DAI, ứng dụng tạo ra yêu cầu phát trực tuyến cho quảng cáo và video nội dung, VOD hoặc nội dung trực tiếp. Sau đó, SDK này sẽ trả về một luồng video kết hợp, để bạn không phải quản lý việc chuyển đổi giữa quảng cáo và video nội dung trong ứng dụng của bạn.

Chọn giải pháp DAI mà bạn quan tâm

Dịch vụ trọn gói Phân phát nhóm

DAI (Chèn quảng cáo động) đầy đủ dịch vụ

Hướng dẫn này minh hoạ cách tích hợp SDK IMA DAI vào một trình phát video đơn giản . Nếu bạn muốn xem hoặc theo dõi một mẫu hoàn chỉnh hãy tải báo cáo cơ bản ví dụ trên GitHub.

Lưu ý: SDK IMA DAI dành cho Roku hỗ trợ cả luồng HLS và DASH mà không có sự khác biệt về cách triển khai.

Để sử dụng IMA DAI, bạn phải có Tài khoản Ad Manager 360 nâng cao. Nếu bạn có tài khoản Ad Manager, hãy liên hệ với người quản lý tài khoản của bạn để biết thêm chi tiết. Để biết thông tin về việc đăng ký Ad Manager, hãy truy cập vào Trung tâm trợ giúp Ad Manager.

Lưu ý: Để biết thông tin về cách tích hợp với các nền tảng khác hoặc về cách sử dụng SDK phía máy khách IMA, hãy xem SDK quảng cáo trên phương tiện truyền thông tương tác.

Tổng quan về IMA DAI

Việc triển khai IMA DAI liên quan đến hai thành phần SDK chính, như được minh hoạ trong ví dụ này hướng dẫn:

• StreamRequest: Đối tượng xác định yêu cầu luồng. Các yêu cầu phát trực tiếp có thể là video theo yêu cầu hoặc video theo yêu cầu trực tiếp phát trực tuyến. Các yêu cầu sẽ chỉ định một Content ID, cũng như một khoá API hoặc mã xác thực và các thông tin tham số.
• StreamManager: Đối tượng xử lý luồng chèn quảng cáo động và hoạt động tương tác với phần phụ trợ DAI. Chiến lược phát hành đĩa đơn Trình quản lý luồng cũng xử lý các ping theo dõi cũng như chuyển tiếp các sự kiện luồng và quảng cáo đến nhà xuất bản.

Điều kiện tiên quyết

• Hãy đọc kỹ trang về khả năng tương thích của chúng tôi để đảm bảo trường hợp sử dụng mà bạn mong muốn được hỗ trợ.
• Tải trình phát mẫu Roku xuống mã
• Triển khai mã trình phát mẫu cho thiết bị Roku để xác minh rằng quy trình phát triển đang hoạt động.

Phát video của bạn

Trình phát video mẫu được cung cấp sẽ phát một video nội dung ngay từ đầu. Triển khai trình phát mẫu sang trình phát Roku để đảm bảo môi trường phát triển của bạn thiết lập đúng cách.

Chuyển trình phát video của bạn thành trình phát luồng IMA DAI

Làm theo các bước sau để triển khai trình phát sự kiện phát trực tiếp.

Tạo Sdk.xml

Thêm một tệp mới vào dự án cùng với MainScene.xml có tên là Sdk.xml. rồi thêm mã nguyên mẫu sau:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
  ' Your code goes here.
]]>
</script>
</component>

Bạn cần phải chỉnh sửa cả hai tệp này trong suốt hướng dẫn này.

Tải Khung quảng cáo Roku

SDK IMA DAI phụ thuộc vào Khung quảng cáo Roku. Để tải khung, thêm đoạn mã sau vào manifest và Sdk.xml:

tệp kê khai

bs_libs_required=roku_ads_lib,googleima3

Sdk.xml

Library "Roku_Ads.brs"
Library "IMA3.brs"

Tải SDK IMA DAI

Bước đầu tiên để tải luồng Chèn quảng cáo động IMA là tải và khởi chạy SDK IMA DAI. Các tệp sau đây tải tập lệnh SDK IMA DAI.

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
</interface>
...
Sub init()
  m.top.functionName = "runThread"
End Sub

Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
End Sub

Sub loadSdk()
    If m.sdk = invalid
      m.sdk = New_IMASDK()
    End If
    m.top.sdkLoaded = true
End Sub

Bây giờ, hãy bắt đầu việc cần làm này trong MainScene.xml và xoá lệnh gọi để tải nội dung luồng.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  loadImaSdk()
end function

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  m.sdkTask.control = "RUN"
end function

Sub onSdkLoaded(message as Object)
  print "----- onSdkLoaded --- control ";message
End Sub

Sub onSdkLoadedError(message as Object)
  print "----- errors in the sdk loading process --- ";message
End Sub

Tạo trình phát luồng IMA

Tiếp theo, bạn cần sử dụng roVideoScreen hiện có để tạo luồng IMA trình phát. Trình phát trực tuyến này triển khai 3 phương thức gọi lại: loadUrl, adBreakStarted và adBreakEnded. Ngoài ra, hãy tắt tính năng phát mẹo khi phát trực tiếp đã được tải. Điều này giúp người dùng không bỏ qua quảng cáo trước video ngay khi quảng cáo đó xuất hiện bắt đầu, trước khi sự kiện điểm chèn quảng cáo bắt đầu được kích hoạt.

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
  sdk = m.sdk
  m.player = sdk.createPlayer()
  m.player.top = m.top
  m.player.loadUrl = Function(urlData)
    m.top.video.enableTrickPlay = false
    m.top.urlData = urlData
  End Function
  m.player.adBreakStarted = Function(adBreakInfo as Object)
    print "---- Ad Break Started ---- "
    m.top.adPlaying = True
    m.top.video.enableTrickPlay = false
  End Function
  m.player.adBreakEnded = Function(adBreakInfo as Object)
    print "---- Ad Break Ended ---- "
    m.top.adPlaying = False
    m.top.video.enableTrickPlay = true
  End Function
End Sub

Tạo và thực thi yêu cầu luồng

Giờ đây, khi đã có trình phát trực tuyến, bạn có thể tạo và thực thi yêu cầu phát trực tuyến. Ví dụ này có dữ liệu về một sự kiện phát trực tiếp và một sự kiện phát trực tiếp VOD. Kênh này sử dụng video theo yêu cầu phát trực tiếp, nhưng bạn có thể sử dụng tính năng phát trực tiếp bằng cách thay đổi selectedStream từ m.testVodStream đến m.testLiveStream.

Để có thể hỗ trợ AdUI, chẳng hạn như biểu tượng adChoices, bạn cũng phải truyền một tham chiếu đến nút chứa video nội dung của bạn như một phần của yêu cầu.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testLiveStream = {
    title: "Livestream",
    assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
    apiKey: "",
    type: "live"
  }
  m.testVodStream = {
    title: "VOD stream"
    contentSourceId: "2548831",
    videoId: "tears-of-steel",
    apiKey: "",
    type: "vod"
  }
  loadImaSdk()
end function

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  selectedStream = m.testVodStream
  m.videoTitle = selectedStream.title
  m.sdkTask.streamData = selectedStream

  m.sdkTask.video = m.video
  m.sdkTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="video" type="Node" />
  <field id="streamData" type="assocarray" />
  <field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
  if not m.top.streamManagerReady
    loadStream()
  End If
End Sub

Sub loadStream()
  sdk = m.sdk
  sdk.initSdk()
  setupVideoPlayer()

  request = {}
  streamData = m.top.streamData
  if streamData.type = "live"
    request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
  else if streamData.type = "vod"
    request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
  else
    request = sdk.CreateStreamRequest()
  end if

  request.player = m.player
  request.videoObject = m.top.video
  ' Required to support UI elements for 'Why This Ad?' and skippability
  request.adUiNode = m.top.video

  requestResult = sdk.requestStream(request)
  If requestResult &lt;&gt; Invalid
    print "Error requesting stream ";requestResult
  Else
    m.streamManager = Invalid
    While m.streamManager = Invalid
      sleep(50)
      m.streamManager = sdk.getStreamManager()
    End While
    If m.streamManager = Invalid or m.streamManager["type"] &lt;&gt; Invalid or m.streamManager["type"] = "error"
      errors = CreateObject("roArray", 1, True)
      print "error ";m.streamManager["info"]
      errors.push(m.streamManager["info"])
      m.top.errors = errors
    Else
      m.top.streamManagerReady = True
      addCallbacks()
      m.streamManager.start()
    End If
  End If
End Sub

Thêm trình nghe sự kiện và bắt đầu phát trực tiếp

Sau khi yêu cầu phát trực tiếp, bạn chỉ còn một vài việc cần làm là thêm sự kiện để theo dõi tiến trình quảng cáo, bắt đầu phát trực tiếp và chuyển tiếp tin nhắn Roku đến SDK.

Lưu ý quan trọng: Bạn phải chuyển tiếp tất cả thông báo đến SDK để đảm bảo quảng cáo chính xác phát.

MainScene.xml

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  selectedStream = m.testVodStream
  m.videoTitle = selectedStream.title
  m.sdkTask.streamData = selectedStream

  m.sdkTask.observeField("urlData", "urlLoadRequested")
  m.sdkTask.video = m.video
  m.sdkTask.control = "RUN"
end function

Sub urlLoadRequested(message as Object)
  print "Url Load Requested ";message
  data = message.getData()

  playStream(data.manifest)
End Sub

Sub playStream(url as Object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.videoTitle
  vidContent.streamformat = "hls"
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
End Sub

Sdk.xml

Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
  if not m.top.streamManagerReady
    loadStream()
  End If
  If m.top.streamManagerReady
    runLoop()
  End If
End Sub

Sub runLoop()
  m.top.video.timedMetaDataSelectionKeys = ["*"]

  m.port = CreateObject("roMessagePort")

  ' Listen to all fields.

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  fields = m.top.video.getFields()
  for each field in fields
    m.top.video.observeField(field, m.port)
  end for

  while True
    msg = wait(1000, m.port)
    if m.top.video = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.video.position
    If currentTime > 3 And not m.top.adPlaying
       m.top.video.enableTrickPlay = true
    End If
  end while
End Sub

Function addCallbacks() as Void
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function

Function startCallback(ad as Object) as Void
  print "Callback from SDK -- Start called - "
End Function

Function firstQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- First quartile called - "
End Function

Function midpointCallback(ad as Object) as Void
  print "Callback from SDK -- Midpoint called - "
End Function

Function thirdQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- Third quartile called - "
End Function

Function completeCallback(ad as Object) as Void
  print "Callback from SDK -- Complete called - "
End Function

Function errorCallback(error as Object) as Void
  print "Callback from SDK -- Error called - "; error
  m.errorState = True
End Function

Thêm tính năng hỗ trợ cho quảng cáo có thể bỏ qua (không bắt buộc)

Để hỗ trợ quảng cáo có thể bỏ qua, bạn cần thêm phương thức seek vào trình phát của SDK IMA DAI đối tượng được lập trình tìm kiếm video đến vị trí được chỉ định, trong giây.

Để hỗ trợ quảng cáo có thể bỏ qua, bạn cũng phải đảm bảo đặt adUiNode trong yêu cầu của bạn.

Sdk.xml

  m.player.loadUrl = Function(urlData)
    m.top.video.enableTrickPlay = false
    m.top.urlData = urlData
  End Function

  m.player.seek = Function(timeSeconds as Float)
     print "---- SDK requested seek to ----" ; timeSeconds
     m.top.video.seekMode = "accurate"
     m.top.video.seek = timeSeconds
  End Function

  m.player.adBreakStarted = Function(adBreakInfo as Object)
    print "---- Ad Break Started ---- "
    m.top.adPlaying = True
    m.top.video.enableTrickPlay = false
  End Function